
    InstructorLite

Structured prompting for LLMs. InstructorLite is a fork, spiritual successor and almost an entire rewrite of instructor_ex library.
InstructorLite provides basic building blocks to embed LLMs into your
application. It uses Ecto schemas to make sure LLM output has a predictable
shape and can play nicely with deterministic application logic. For an example
of what can be built with InstructorLite, check out
Handwave
Why Lite
InstructorLite is designed to be:
	Lean. It does so little it makes you question if you should just write your own version!
	Composable. Almost everything it does can be overridden or extended.
	Magic-free. It doesn't hide complexity behind one line function calls, but does its best to provide you with enough information to understand what's going on.

InstructorLite is tested to be compatible with the following providers:
OpenAI, Anthropic,
Gemini and any Chat Completions-compatible APIs, such as Grok.
Features
InstructorLite can be boiled down to these features:
	It provides a very simple function for generating JSON schema from Ecto schema.
	It facilitates generating prompts, calling LLMs, casting and validating responses, including retrying prompts when validation fails.
	It holds knowledge of major LLM providers' API interfaces with adapters.

Any of the features above can be used independently.
Usage
Define an instruction, which is a normal Ecto schema with an extra use Instructor.Instruction call.
defmodule UserInfo do
  use Ecto.Schema
  use InstructorLite.Instruction
  
  @primary_key false
  embedded_schema do
    field(:name, :string)
    field(:age, :integer)
  end
end
Now let's use InstructorLite.instruct/2 to fill the schema from unstructured text:
OpenAI
iex> InstructorLite.instruct(%{
    input: [
      %{role: "user", content: "John Doe is forty-two years old"}
    ]
  },
  response_model: UserInfo,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :openai_key)]
)
{:ok, %UserInfo{name: "John Doe", age: 42}}
Anthropic
iex> InstructorLite.instruct(%{
    messages: [
      %{role: "user", content: "John Doe is forty-two years old"}
    ]
  },
  response_model: UserInfo,
  adapter: InstructorLite.Adapters.Anthropic,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :anthropic_key)]
)
{:ok, %UserInfo{name: "John Doe", age: 42}}
Llamacpp
iex> InstructorLite.instruct(%{
    prompt: "John Doe is forty-two years old"
  },
  response_model: UserInfo,
  adapter: InstructorLite.Adapters.Llamacpp,
  adapter_context: [url: Application.fetch_env!(:instructor_lite, :llamacpp_url)]
)
{:ok, %UserInfo{name: "John Doe", age: 42}}
Gemini
iex> InstructorLite.instruct(%{
    contents: [
      %{
        role: "user",
        parts: [%{text: "John Doe is forty-two years old"}]
      }
    ]
  },
  response_model: UserInfo,
  json_schema: %{
    type: "object",
    required: [:age, :name],
    properties: %{name: %{type: "string"}, age: %{type: "integer"}},
  },
  adapter: InstructorLite.Adapters.Gemini,
  adapter_context: [
    api_key: Application.fetch_env!(:instructor_lite, :gemini_key)
  ]
)
{:ok, %UserInfo{name: "John Doe", age: 42}}
Grok
Grok API is compatible with OpenAI Chat Completions endpoint, so we can use
the ChatCompletionsCompatible adapter with Grok's url and model_name
iex> InstructorLite.instruct(%{
    model: "grok-3-latest",
    messages: [
      %{role: "user", content: "John Doe is forty-two years old"}
    ]
  },
  response_model: UserInfo,
  adapter: InstructorLite.Adapters.ChatCompletionsCompatible,
  adapter_context: [
    url: "https://api.x.ai/v1/chat/completions",
    api_key: Application.fetch_env!(:instructor_lite, :grok_key)
  ]
)
{:ok, %UserInfo{name: "John Doe", age: 42}}
Configuration
InstructorLite does not access the application environment for configuration options like adapter or API key. Instead, they're passed as options when needed. Note that different adapters may require different options, so make sure to check their documentation.
Approach to development
InstructorLite is hand-written by a human and all external contributions are
vetted by a human. And said human is committed to keep it this way for
foreseeable future. This comes with both advantages and drawbacks. The library
may be prone to silly human errors and poor judgement, but at the same time it
is likely won't explode in complexity overnight or undergo a full rewrite every
couple of months. Tune your expectations accordingly! 
Non-goals
InstructorLite very explicitly doesn't pursue the following goals:
	Response streaming. Streaming is good UX for cases when LLM output is relayed
to users, but doesn't make much sense for application environment, where
structured outputs are usually used.
	Unified interface. We acknowledge that LLM providers can be very different
and trying to fit them under the same roof brings a ton of unnecessary
complexity. Instead, InstructorLite aims to make it simple for developers to
understand these differences and grapple with them.

Installation
In your mix.exs, add :instructor_lite to your list of dependencies:
def deps do
  [
    {:instructor_lite, "~> 1.3.0"}
  ]
end
Optionally, include Req HTTP client (used by default) and Jason (for Elixir older than 1.18):
def deps do
  [
    {:req, "~> 0.5 or ~> 1.0"},
    {:jason, "~> 1.4"}
  ]
end


  

    Migrating from Instructor

InstructorLite is not meant as a drop-in replacement for Instructor, so there are a number of things to consider when making a decision to switch.
✅ You might want to switch if:
	You need more customization (e.g. using Tesla instead of Req)
	You want to have fine-grained control over side-effects (e.g. delay executing requests to use Batch API)
	You plan to tinker with the library's source code or write your own adapters
	You've run into issues and and are on the path to your own fork

❌ You might not want to switch if:
	Instructor already works for you and you want things to continue to "just work"
	You need streaming capabilities

Migrating Schemas
Instructor works with any Ecto schema and optionally allows you to use Instructor.Validator behaviour for the Instructor.Validator.validate_changeset/2 callback.
InstructorLite can also work with any Ecto schema, but it doesn't use the @doc attribute for semantic description. Instead, you can use InstructorLite.Instruction and define the @notes attribute. The InstructorLite.Instruction.validate_changeset/2 callback is still here, but it's always of arity 2.
As a result, you don't have to add a docstring in your release.
Instructor
defmodule SpamPrediction do
  use Ecto.Schema
  use Instructor.Validator

  @doc """
  ## Field Descriptions:
  - class: Whether or not the email is spam.
  - reason: A short, less than 10 word rationalization for the classification.
  - score: A confidence score between 0.0 and 1.0 for the classification.
  """
  @primary_key false
  embedded_schema do
    field(:class, Ecto.Enum, values: [:spam, :not_spam])
    field(:reason, :string)
    field(:score, :float)
  end

  @impl true
  def validate_changeset(changeset) do
    changeset
    |> Ecto.Changeset.validate_number(:score,
      greater_than_or_equal_to: 0.0,
      less_than_or_equal_to: 1.0
    )
  end
end
# mix.exs
def project do
  # ...
  releases: [
    myapp: [
      strip_beams: [keep: ["Docs"]]
    ]
  ]
end
InstructorLite
defmodule SpamPrediction do
  use Ecto.Schema
  use InstructorLite.Instruction

  @notes """
  ## Field Descriptions:
  - class: Whether or not the email is spam.
  - reason: A short, less than 10 word rationalization for the classification.
  - score: A confidence score between 0.0 and 1.0 for the classification.
  """
  @primary_key false
  embedded_schema do
    field(:class, Ecto.Enum, values: [:spam, :not_spam])
    field(:reason, :string)
    field(:score, :float)
  end

  @impl InstructorLite.Instruction
  def validate_changeset(changeset, _opts) do
    changeset
    |> Ecto.Changeset.validate_number(:score,
      greater_than_or_equal_to: 0.0,
      less_than_or_equal_to: 1.0
    )
  end
end
Migrating Instructor.chat_completions/2
Instructor.chat_completion/2 works primarily with params, but also accepts an optional config as the second argument. Some parameters are passed to the LLM and some control Instructor's own behavior.
The InstructorLite equivalent function is InstructorLite.instruct/2. It also accepts params as the first argument, but many params were moved to the second opts argument. Read more about this in Key Concepts.
In addition, InstructorLite does not access application configuration, so API keys are typically passed through opts.
Instructor
Instructor.chat_completion(%{
  model: "gpt-3.5-turbo",
  response_model: SpamPrediction,
  messages: [
    %{
      role: "user",
      content: "Classify the following text: Hello, I am a Nigerian prince and I would like to give you $1,000,000."
    }
  ]
})
{:ok, %SpamPrediction{class: :spam, score: 0.999}}
# config.exs
config :instructor, 
  adapter: Instructor.Adapters.OpenAI,
  openai: [api_key: "my_secret_key"]
InstructorLite
InstructorLite.instruct(%{
    input: [
      %{
        role: "user",
        content: "Classify the following text: Hello, I am a Nigerian prince and I would like to give you $1,000,000."
      }
    ],
    model: "gpt-4o-mini"
  },
  response_model: SpamPrediction,
  adapter: InstructorLite.Adapters.OpenAI,
  adapter_context: [api_key: "my_secret_key"]
)
{:ok, %SpamPrediction{class: :spam, score: 0.999}}
Migrating Custom Ecto Types
Instructor.EctoType allows you to define a way to dump a custom Ecto type to JSON schema using the Instructor.EctoType.to_json_schema/0 callback.
InstructorLite lowers the bar for the built-in Ecto-to-JSON-schema converter. It only works for basic Ecto types and may not be compatible with all LLMs. As soon as basic JSON schema is not enough for you, you should define the schema manually using the InstructorLite.Instruction.json_schema/0 callback.
Instructor
defmodule Ecto.CSVDataFrame do
  use Ecto.Type
  use Instructor.EctoType

  def type, do: :string

  def cast(csv_str) when is_binary(csv_str) do
    df = Explorer.DataFrame.load_csv!(csv_str)
    {:ok, df}
  end

  def cast(%Explorer.DataFrame{} = df), do: {:ok, df}
  def cast(_), do: :error

  def to_json_schema(),
    do: %{
      type: "string",
      description: "A CSV representation of a data table"
    }

  def dump(x), do: {:ok, x}
  def load(x), do: {:ok, x}
end
defmodule Database do
  use Ecto.Schema
  use Instructor.Validator

  @doc """
  The extracted database will contain one or more tables with data as csv formatted with ',' delimiters
  """
  @primary_key false
  embedded_schema do
    embeds_many :tables, DataFrame, primary_key: false do
      field(:name, :string)
      field(:data, Ecto.CSVDataFrame)
    end
  end
end
InstructorLite
defmodule Ecto.CSVDataFrame do
  use Ecto.Type

  def type, do: :string

  def cast(csv_str) when is_binary(csv_str) do
    df = Explorer.DataFrame.load_csv!(csv_str)
    {:ok, df}
  end

  def cast(%Explorer.DataFrame{} = df), do: {:ok, df}
  def cast(_), do: :error

  def dump(x), do: {:ok, x}
  def load(x), do: {:ok, x}
end
defmodule Database do
  use Ecto.Schema
  use InstructorLite.Instruction

  @notes """
  The extracted database will contain one or more tables with data as csv formatted with ',' delimiters
  """
  @primary_key false
  embedded_schema do
    embeds_many :tables, DataFrame, primary_key: false do
      field(:name, :string)
      field(:data, Ecto.CSVDataFrame)
    end
  end
  
  @impl InstructorLite.Instruction
  def json_schema do
    %{
      type: "object",
      description: "",
      title: "Database",
      required: [:tables],
      "$defs": %{
        "DataFrame" => %{
          type: "object",
          description: "",
          title: "DataFrame",
          required: [:data, :name],
          properties: %{data: %{type: "string"}, name: %{type: "string"}},
          additionalProperties: false
        }
      },
      properties: %{tables: %{type: "array", items: %{"$ref": "#/$defs/DataFrame"}}},
      additionalProperties: false
    }
  end
end
Migrating Instructor.validate_with_llm/2
Instructor.Validator.validate_with_llm/2 is a nifty function that allows you to use LLM to validate your changeset.
InstructorLite doesn't have this function. Instead, you can write your own thin helper function.
Instructor
defmodule QuestionAnswer do
  use Ecto.Schema
  use Instructor.Validator

  @primary_key false
  embedded_schema do
    field(:question, :string)
    field(:answer, :string)
  end

  @impl true
  def validate_changeset(changeset) do
    changeset
    |> validate_with_llm(:answer, "Do not say anything objectionable")
  end
end
%QuestionAnswer{}
|> Instructor.cast_all(%{
  question: "What is the meaning of life?",
  answer: "Sex, drugs, and rock'n roll"
})
|> QuestionAnswer.validate_changeset()

#Ecto.Changeset<
  action: nil,
  changes: %{question: "What is the meaning of life?", answer: "Sex, drugs, and rock'n roll"},
  errors: [answer: {"is invalid, Do not say anything objectionable", []}],
  data: #QuestionAnswer<>,
  valid?: false
>
InstructorLite
defmodule QuestionAnswer do
  use Ecto.Schema

  @primary_key false
  embedded_schema do
    field :question, :string
    field :answer, :string
  end

  def changeset(data, params) do
    data
    |> Ecto.Changeset.cast(params, [:answer])
    |> validate_with_llm(:answer, "do not say anything objectionable")
  end

  def validate_with_llm(changeset, field, rule) do
    Ecto.Changeset.validate_change(changeset, field, fn ^field, value ->
      %{
        input: [
          %{
            role: "system",
            content: """
            You are a world-class validation model. Capable of determining if the following value is valid for the statement, if it is not, explain why.
            """
          },
          %{
            role: "user",
            content: "Does `#{value}` follow the rule: #{rule}"
          }
        ]
      }
      |> InstructorLite.instruct(
        response_model: %{valid?: :boolean, reason: :string},
        adapter_context: [api_key: "my_api_token"]
      )
      |> case do
        {:ok, %{valid?: false, reason: reason}} ->
          [{field, reason}]

        _ -> []
      end
    end)
  end
end
%QuestionAnswer{question: "What is the meaning of life?"}
|> QuestionAnswer.changeset(%{answer: "Sex, drugs, and rock'n roll"})

#Ecto.Changeset<
  action: nil,
  changes: %{answer: "Sex, drugs, and rock'n roll"},
  errors: [
    answer: {"The phrase 'Sex, drugs, and rock'n roll' contains references to explicit content, substance use, and a lifestyle that may be considered objectionable or inappropriate by many standards.",
     []}
  ],
  data: #QuestionAnswer<>,
  valid?: false,
  ...
>
Migrating Llamacpp Usage
Instructor's Llamacpp was implemented through converting JSON schema to GBNF grammar.
InstructorLite offers a very basic Llamacpp adapter which passes JSON schema to the Llamacpp server. If you want to use Llamacpp with InstructorLite, you will likely need to learn how your model of choice works and write your own adapter. InstructorLite can offer you a flexible enough chassis to build upon, but doesn't have much expertise to share 🫡.


  

    Local Development Guide

You should be able to run most tests out of the box:
mix deps.get
mix test
However, to actually be able to query LLMs, you'll need to put your own personal API keys into a config/config.exs, which is ignored by Git. Start by copying config/config.example.exs:
cp config/config.example.exs config/config.exs
Depending on what secrets you have, you'll be able to run integration tests for different adapters. All integration tests can be found in test/integration_test.exs. Here's how to run the OpenAI suite:
mix test test/integrations/openai_test.exs


  

    Changelog

v1.3.0
	Add InstructorLite.Adapters.ResponsesCompatible adapter. OpenAI
adapter remains but will simply delegate to it under the hood.
	Update Gemini adapter default model to gemini-3.5-flash-lite

v1.2.0
	Switch Gemini adapter to responseJsonSchema parameter which is much more
chill than the previous responseSchema parameter. If you previously
employed any workaround for Gemini json schemas, you can likely remove
them now.
	Update Anthropic adapter default model to claude-haiku-4-5
	Use structured
outputs
in Anthropic adapter for models that support it

v1.1.2
	Pass Gemini token in request header rather than in request parameter (as is shown in API reference 😬)
	Add integration test for ChatCompletionsCompatible adapter with Gemini

v1.1.1
	Fix a bug when ChatCompletionsCompatible adapter would not work correctly
with providers that don't return refusal field (Mistral)
	Fix rare bug when InstructorLite.ask/2 would fail in non-release environments

v1.1.0
	Library now requires Elixir 1.15+
	Introduces new InstructorLite.ask/2 function for cases where you need plain non-structured output.
	To accommodate non-structured output, a new optional
InstructorLite.Adapter.find_output/2 callback was added to the adapter
behaviour. If you're using a custom adapter, consider implementing it if you
want to use InstructorLite.ask/2

v1.0.0
	OpenAI adapter is changed to use the
Responses API.
The chat completions-based adapter is still available as
InstructorLite.Adapters.ChatCompletionsCompatible
	Jason dependency is now optional
	All adapters have been tested and verified for compatibility with reasoning models
	Default prompts have been refined and standardized across adapters

Migrating to 1.0.0
	If you use the OpenAI adapter and want to continue using the chat completions endpoint, switch to the ChatCompletionsCompatible adapter:InstructorLite.instruct(%{
 messages: [
   %{role: "user", content: "John Doe is fourty two years old"}
 ]
},
response_model: %{name: :string, age: :integer},
-   adapter: InstructorLite.Adapters.OpenAI,
+   adapter: InstructorLite.Adapters.ChatCompletionsCompatible,
adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :openai_key)]
)

	If you use the OpenAI adapter and want to switch to the responses endpoint, update params to comply with the POST /v1/responses interface. Most notably, the messages key should be input:InstructorLite.instruct(%{
-    messages: [
+    input: [
   %{role: "user", content: "John Doe is fourty two years old"}
 ]
},
response_model: %{name: :string, age: :integer},
adapter: InstructorLite.Adapters.OpenAI,
adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :openai_key)]
)


v0.3.0
	Add Gemini adapter

v0.2.0
	[OpenAI] Do not overwrite response_format params key if provided by the user
	Fix consume_response/3 enforcing all keys to present for ad-hoc Ecto schemas
	Add Local Development Guide

v0.1.0
	Initial release



  

    Text Classification

Mix.install(
  [
    {:instructor_lite, "~> 1.0"},
    {:req, "~> 0.5"}
  ]
)
Motivation
Text classification is a common task in NLP and broadly applicable across software. Whether it be spam detection or support ticket categorization, NLP is at the core. Historically, this required training custom, bespoke models that required collecting thousands of pre-labeled examples. With LLMs, a lot of this knowledge is already encoded into the model. With proper instruction and guiding the output to a known set of classifications using GPT, you can be up and running with a text classification model in no time.
Hell, you can even use instructor to help generate the training set to train your own more efficient model. But let's not get ahead of ourselves, there's more on that later in the tutorials.
Setup
In order to run code in this notebook, you need to add your OpenAI API key as an OPENAI_KEY Livebook secret. It will then be accessible through an environmental variable.
secret_key = System.fetch_env!("LB_OPENAI_KEY")
:ok
:ok
Binary Text Classification
Spam detection is a classic example of binary text classification. It's as simple as returning a true / false of whether an example is in the class. This is pretty trivial to implement in instructor.
defmodule SpamPrediction do
  use Ecto.Schema
  use InstructorLite.Instruction

  @notes """
  ## Field Descriptions:
  - class: Whether or not the email is spam.
  - reason: A short, less than 10 word rationalization for the classification.
  - score: A confidence score between 0.0 and 1.0 for the classification.
  """
  @primary_key false
  embedded_schema do
    field(:class, Ecto.Enum, values: [:spam, :not_spam])
    field(:reason, :string)
    field(:score, :float)
  end

  @impl true
  def validate_changeset(changeset, _opts) do
    changeset
    |> Ecto.Changeset.validate_number(:score,
      greater_than_or_equal_to: 0.0,
      less_than_or_equal_to: 1.0
    )
  end
end

is_spam? = fn text ->
  InstructorLite.instruct(%{
      model: "gpt-4o-mini",
      input: [
        %{
          role: "user",
          content: """
          Your purpose is to classify customer support emails as either spam or not.
          This is for a clothing retail business.
          They sell all types of clothing.
  
          Classify the following email: 
          ```
          #{text}
          ```
          """
        }
      ]
    },
    response_model: SpamPrediction,
    max_retries: 1,
    adapter_context: [api_key: secret_key]
  )
end

is_spam?.("Hello I am a Nigerian prince and I would like to send you money")
{:ok, %SpamPrediction{class: :spam, reason: "Common spam trope", score: 0.95}}
We don't have to stop just at a boolean inclusion, we can also easily extend this idea to multiple categories or classes that we can classify the text into. In this example, let's consider classifying support emails. We want to know whether it's a general_inquiry, billing_issue, or a technical_issue perhaps it rightly fits in multiple classes. This can be useful if we want to cc' specialized support agents when intersecting customer issues occur
We can leverage Ecto.Enum to define a schema that restricts the LLM output to be a list of those values. We can also provide a @notes description to help guide the LLM with the semantic understanding of what these classifications ought to represent.
defmodule EmailClassifications do
  use Ecto.Schema
  use InstructorLite.Instruction

  @notes """
  A classification of a customer support email.

  technical_issue - whether the user is having trouble accessing their account
  billing_issue - whether the customer is having trouble managing their billing or credit card
  general_inquiry - all other issues
  """
  @primary_key false
  embedded_schema do
    field(:tags, {:array, Ecto.Enum},
      values: [:general_inquiry, :billing_issue, :technical_issue]
    )
  end
end

classify_email = fn text ->
  {:ok, %{tags: result}} =
    InstructorLite.instruct(%{
        input: [
          %{
            role: "user",
            content: "Classify the following text: #{text}"
          }
        ]
      },
      response_model: EmailClassifications,
      adapter_context: [api_key: secret_key]
    )

  result
end

classify_email.("My account is locked and I can't access my billing info.")
[:technical_issue, :billing_issue]


  

    Computer Vision - Extracting Data from Images

Mix.install(
  [
    {:instructor_lite, "~> 1.0"},
    {:req, "~> 0.5"},
    {:kino, "~> 0.12.3"}
  ]
)
Motivation
In recent months, the latest AI research labs have turned LLMs into multimodal models. What this means is that they no longer just interpret text, but they can also interpret images. One example of this provided by Anthropic is the Claude 3.5 Sonnet model. With no extra work, you can now provide images into your prompts with Instructor and still do the normal structured extractions that you're used to.
In the following example, we will extract product details from a screenshot of a Shopify store.
Setup
In order to run code in this notebook, you need to add your Anthropic API key as an ANTHROPIC_KEY Livebook secret. It will then be accessible through an environment variable.
secret_key = System.fetch_env!("LB_ANTHROPIC_KEY")
:ok
:ok
Example
[image: ]
image = Kino.FS.file_path("shopify-screenshot.png") |> File.read!()
base64_image = Base.encode64(image)

defmodule Product do
  use Ecto.Schema

  @primary_key false
  embedded_schema do
    field(:name, :string)
    field(:price, :decimal)
    field(:currency, Ecto.Enum, values: [:usd, :gbp, :eur, :cny])
    field(:color, :string)
  end
end

{:ok, result} =
  InstructorLite.instruct(%{
      messages: [
        %{
          role: "user",
          content: [
            %{type: "text", text: "What is the product details of the following image?"},
            %{type: "image", source: %{data: base64_image, type: "base64", media_type: "image/png"}}
          ]
        }
      ]
    },
    adapter: InstructorLite.Adapters.Anthropic,
    response_model: Product,
    adapter_context: [api_key: secret_key]
  )

result
%Product{
  name: "Thomas Wooden Railway Thomas The Tank Engine",
  price: Decimal.new("33.0"),
  currency: :usd,
  color: "blue"
}


  

    Converting Text into Explorer DataFrames

Mix.install(
  [
    {:instructor_lite, "~> 1.0"},
    {:req, "~> 0.5"},
    {:explorer, "~> 0.7.2"},
    {:kino, "~> 0.12.0"},
    {:kino_explorer, "~> 0.1.13"}
  ]
)
Motivation
Sometimes we come across text that can be naturally extracted into structured data. Although we don't necessarily know how many tables, and what the schemas are represented in the data. Using Instructor we can let the LLM determine the tables and schemas for us, pulling the results into a dataframe which we can then use for further analysis.
Setup
In order to run code in this notebook, you need to add your OpenAI API key as an OPENAI_KEY Livebook secret. It will then be accessible through an environmental variable.
secret_key = System.fetch_env!("LB_OPENAI_KEY")
:ok
:ok
The Schema
Notice from this example we want resulting data structure to have data frames. That's not a default Ecto type so we're gonna have to do things a little different here.
Luckily, Ecto allows us to define our own custom types in which we can override how the values are casted.
In our case, we're going to create a type for a table of data, which will be represented as a CSV string with respect to the LLM. Our custom type will then parse the string when it is casted by Ecto and parse the CSV into an Explorer.DataFrame.
defmodule Ecto.CSVDataFrame do
  use Ecto.Type

  def type, do: :string

  def cast(csv_str) when is_binary(csv_str) do
    df = Explorer.DataFrame.load_csv!(csv_str)
    {:ok, df}
  end

  def cast(%Explorer.DataFrame{} = df), do: {:ok, df}
  def cast(_), do: :error

  def dump(x), do: {:ok, x}
  def load(x), do: {:ok, x}
end
{:module, Ecto.CSVDataFrame, <<70, 79, 82, 49, 0, 0, 11, ...>>, {:load, 1}}
Now that we have our data type, we can use it in our embedded Ecto schema, just as we would have in any other example. The built-in InstructorLite.JSONSchema module won't help us here, as it doesn't know how to convert a custom Ecto type, so we'll craft our own schema in the json_schema callback. If everything works correctly, we should get some data frames out.
defmodule Database do
  use Ecto.Schema
  use InstructorLite.Instruction

  @notes """
  The extracted database will contain one or more tables with data as csv formatted with ',' delimiters
  """
  @primary_key false
  embedded_schema do
    embeds_many :tables, DataFrame, primary_key: false do
      field(:name, :string)
      field(:data, Ecto.CSVDataFrame)
    end
  end

  @impl InstructorLite.Instruction
  def json_schema() do
    %{
      type: "object",
      description: "",
      title: "Database",
      required: [:tables],
      "$defs": %{
        "DataFrame" => %{
          type: "object",
          description: "",
          title: "DataFrame",
          required: [:data, :name],
          properties: %{data: %{type: "string"}, name: %{type: "string"}},
          additionalProperties: false
        }
      },
      properties: %{tables: %{type: "array", items: %{"$ref": "#/$defs/DataFrame"}}},
      additionalProperties: false
    }
  end
end
{:module, Database, <<70, 79, 82, 49, 0, 0, 18, ...>>, {:json_schema, 0}}
Perfect. And now let's test it out on some example text.
extract_df = fn text ->
  InstructorLite.instruct(%{
      model: "gpt-4o-mini",
      input: [
        %{
          role: "system",
          content: """
          Map this data into one or more dataframes and correctly define the columns and data
          """
        },
        %{
          role: "user",
          content: "#{text}"
        }
      ]
    },
    response_model: Database,
    adapter_context: [api_key: secret_key]
  )
end

{:ok, db} =
  extract_df.("""
    My name is John and I am 25 years old. I live in
    New York and I like to play basketball. His name is
    Mike and he is 30 years old. He lives in San Francisco
    and he likes to play baseball. Sarah is 20 years old
    and she lives in Los Angeles. She likes to play tennis.
    Her name is Mary and she is 35 years old.
    She lives in Chicago.
    
    On one team 'Tigers' the captain is John and there are 12 players.
    On the other team 'Lions' the captain is Mike and there are 10 players.
  """)

Kino.Layout.tabs(
  for table <- db.tables do
    {table.name, table.data}
  end
)


  

    Using OpenAI Batch API

Mix.install(
  [
    {:instructor_lite, "~> 1.0"},
    {:req, "~> 0.5"},
    {:multipart, "0.4.0"}
  ]
)
Motivation
OpenAI offers asynchronous Batch API at a 50% discount. This can make a huge difference on the bill if we have a lot of workload that is done in the background and isn't time-sensitive.
Setup
In order to run code in this notebook, you need to add your OpenAI API key as an OPENAI_KEY Livebook secret. It will then be accessible through an environment variable.
secret_key = System.fetch_env!("LB_OPENAI_KEY")
:ok
:ok
Classifying All the Emails
We'll use our classic email classification example, but this time for a bunch of emails at once.
defmodule SpamPrediction do
  use Ecto.Schema
  use InstructorLite.Instruction

  @notes """
  ## Field Descriptions:
  - class: Whether or not the email is spam.
  - reason: A short, less than 10 word rationalization for the classification.
  - score: A confidence score between 0.0 and 1.0 for the classification.
  """
  @primary_key false
  embedded_schema do
    field(:class, Ecto.Enum, values: [:spam, :not_spam])
    field(:reason, :string)
    field(:score, :float)
  end

  @impl true
  def validate_changeset(changeset, _opts) do
    changeset
    |> Ecto.Changeset.validate_number(:score,
      greater_than_or_equal_to: 0.0,
      less_than_or_equal_to: 1.0
    )
  end
end
{:module, SpamPrediction, <<70, 79, 82, 49, 0, 0, 19, ...>>, {:validate_changeset, 2}}
opts = [
  response_model: SpamPrediction,
  adapter: InstructorLite.Adapters.OpenAI
]

prompts =
  [
    "Hello I am a Nigerian prince and I would like to send you money",
    "Hello I know we never met but I got access to your webcam and have some spicy footage",
    "Elixir Radar Newsletter. Issue #420"
  ]
  |> Enum.map(fn text ->
    InstructorLite.prepare_prompt(%{
        model: "gpt-4o-mini",
        input: [%{
          role: "user",
          content: "Classify first paragraph of an email:\n#{text}"
        }]
      },
      opts
    )
  end)
  |> Enum.with_index()

jsonl =
  prompts
  |> Enum.map(fn {prompt, index} ->
    Jason.encode!(%{custom_id: "#{index}", method: "POST", url: "/v1/responses", body: prompt})
  end)
  |> Enum.join("\n")

multipart =
  Multipart.new()
  |> Multipart.add_part(Multipart.Part.text_field("batch", "purpose"))
  |> Multipart.add_part(
    Multipart.Part.file_content_field("emails.jsonl", jsonl, :file, filename: "emails.jsonl")
  )

auth_headers = [{"Authorization", "Bearer #{secret_key}"}]
mp_headers = [{"Content-Type", Multipart.content_type(multipart, "multipart/form-data")}]

{:ok, %{body: %{"id" => file_id}}} =
  Req.post("https://api.openai.com/v1/files",
    headers: auth_headers ++ mp_headers,
    body: Multipart.body_binary(multipart)
  )

{:ok, %{body: %{"id" => batch_id}}} =
  Req.post("https://api.openai.com/v1/batches",
    json: %{input_file_id: file_id, endpoint: "/v1/responses", completion_window: "24h"},
    headers: auth_headers
  )

:ok
:ok
Now we need to wait a little and fetch the batch result.
{:ok, %{body: %{"output_file_id" => output_file_id}}} =
  Req.get("https://api.openai.com/v1/batches/#{batch_id}", headers: auth_headers)

{:ok, %{body: body}} =
  Req.get("https://api.openai.com/v1/files/#{output_file_id}/content", headers: auth_headers)

result =
  body
  |> String.split("\n", trim: true)
  |> Enum.map(&Jason.decode!/1)
  |> Enum.zip(prompts)
  |> Enum.map(fn {%{"response" => %{"body" => response}}, prompt} ->
    InstructorLite.consume_response(response, prompt, response_model: SpamPrediction)
  end)
[
  ok: %SpamPrediction{class: :spam, reason: "Typical scam offer from prince.", score: 0.95},
  ok: %SpamPrediction{class: :spam, reason: "Suspicious webcam claim", score: 0.95},
  ok: %SpamPrediction{
    class: :not_spam,
    reason: "Newsletter content is not promotional",
    score: 0.85
  }
]


  

    Custom Ollama Adapter

Mix.install(
  [
    {:instructor_lite, "~> 1.1"},
    {:req, "~> 0.5"}
  ]
)
About Ollama
Ollama project provides a way to run open source LLMs locally, provided you have capable hardware.
To run a model, just pick one from the list and run CLI command:
> ollama run deepseek-r1:8b
pulling manifest
pulling e6a7edc1a4d7: 100% ▕███████████████████████████████████████████████████████████████████████████████████████████████▏ 5.2 GB
pulling c5ad996bda6e: 100% ▕███████████████████████████████████████████████████████████████████████████████████████████████▏  556 B
pulling 6e4c38e1172f: 100% ▕███████████████████████████████████████████████████████████████████████████████████████████████▏ 1.1 KB
pulling ed8474dc73db: 100% ▕███████████████████████████████████████████████████████████████████████████████████████████████▏  179 B
pulling f64cd5418e4b: 100% ▕███████████████████████████████████████████████████████████████████████████████████████████████▏  487 B
verifying sha256 digest
writing manifest
success
The open source models come in so many shapes and sizes that it is impractical to try to fit them all into a single adapter. But have no fear, as InstructorLite makes it simple to write one for your specific needs!
Custom Adapter
For this exercise, we'll write a custom adapter for Ollama running the deepseek-r1 model.
To do this, we need to create a module implementing the InstructorLite.Adapter behaviour, which requires four callbacks. Let's go through them one by one.
The first callback is send_request/2, which is responsible for making a call with params to some kind of API endpoint. Looking at the Ollama docs, chat completion seems like a good endpoint to aim for, but there's no need to hardcode it in the adapter. We'll just require callers to provide it in full, including hostname and port. Since this is a model running locally, it will likely be something like http://localhost:11434/api/chat.
defmodule OllamaAdapterSendRequest do
  def send_request(params, options) do
    # Remember, adapter-specific options are nested under `adapter_context` key
    url = options |> Keyword.get(:adapter_context, []) |> Keyword.fetch!(:url)

    case Req.post(url, json: params) do
      {:ok, %{status: 200, body: body}} -> {:ok, body}
      {:ok, response} -> {:error, response}
      {:error, reason} -> {:error, reason}
    end
  end
end
{:module, OllamaAdapterSendRequest, <<70, 79, 82, 49, 0, 0, 8, ...>>, {:send_request, 2}}
The next callback is initial_prompt/2. This one enriches user-provided params with whatever is necessary to convince the LLM to fill the JSON schema. This part is very model-specific, so we need to consult the docs.
Fast forward, after reading the model card, the chat completion endpoint documentation and some explorative testing, we see that the endpoint supports structured output and all we need to do is to provide json schema in format parameter. Okay, let's implement the initial_prompt/2 callback with this knowledge.
defmodule OllamaAdapterInitialPrompt do
  def initial_prompt(params, opts) do
    # This prompt will be a message with a "system" role
    sys_message = [
      %{
        role: "system",
        content: InstructorLite.Prompt.prompt(opts)
      }
    ]

    params
    # This adapter might work with different models,
    # so let's put a default one but now insist on it
    |> Map.put_new(:model, "deepseek-r1:8b")
    |> Map.put(:stream, false)
    # The user has likely provided their own prompt, so we need to be nice and not overwrite it
    |> Map.update(:messages, sys_message, fn msgs -> sys_message ++ msgs end)
    |> Map.put(:format, Keyword.fetch!(opts, :json_schema))
  end
end
{:module, OllamaAdapterInitialPrompt, <<70, 79, 82, 49, 0, 0, 9, ...>>, {:initial_prompt, 2}}
At this point, we can actually try to combine both callbacks and see if we can get a response.
json_schema = InstructorLite.JSONSchema.from_ecto_schema(%{name: :string})
prompt = OllamaAdapterInitialPrompt.initial_prompt(%{messages: [
  %{role: "user", content: "Who was the first president of the united states?"}
]}, json_schema: json_schema)
%{
  messages: [
    %{
      role: "system",
      content: "You're called by an Elixir application through the InstructorLite library. Your task is to understand what the application wants you to do and respond with JSON output that matches the schema. The output will be validated by the application against an Ecto schema and potentially some custom rules. You may be asked to adjust your response if it doesn't pass validation. "
    },
    %{role: "user", content: "Who was the first president of the united states?"}
  ],
  stream: false,
  format: %{
    type: "object",
    title: "root",
    required: [:name],
    additionalProperties: false,
    properties: %{name: %{type: "string"}}
  },
  model: "deepseek-r1:8b"
}
url = "http://localhost:11434/api/chat"
{:ok, response} = OllamaAdapterSendRequest.send_request(prompt, adapter_context: [url: url])
{:ok,
 %{
   "created_at" => "2025-08-25T01:19:07.12172Z",
   "done" => true,
   "done_reason" => "stop",
   "eval_count" => 14,
   "eval_duration" => 1404543334,
   "load_duration" => 81403708,
   "message" => %{
     "content" => "{\n  \"name\": \"George_Washington\"\n}\n\n  ",
     "role" => "assistant"
   },
   "model" => "deepseek-r1:8b",
   "prompt_eval_count" => 84,
   "prompt_eval_duration" => 342887500,
   "total_duration" => 1831366625
 }}
Great! This brings us to the parse_response/2 callback. Its job is to extract a parsed JSON object from the raw response, which we'll subsequently attempt to cast to our Ecto schema.
defmodule OllamaAdapterParseResponse do
  def parse_response(response, _opts) do
    case response do
      %{"message" => %{"content" => json}} ->
        InstructorLite.JSON.decode(json)

      other ->
        {:error, :unexpected_response, other}
    end
  end
end

{:ok, params} = OllamaAdapterParseResponse.parse_response(response, [])
{:ok, %{"name" => "George_Washington"}}
That is actually enough for a happy path! But there is one more callback that deals with cases when the output doesn't quite adhere to the schema. Imagine if we received a different response from a model:
hypothetical = %{"name" => false}
changeset = Ecto.Changeset.cast({%{}, %{name: :string}}, hypothetical, [:name])
errors = InstructorLite.ErrorFormatter.format_errors(changeset)
"name - is invalid"
We need to retry our query and relay the errors to the model, so it can correct its previous answer. retry_callback/5 is the biggest callback of all, simply because it can potentially need so much context to do that. It needs to know what params were, which data we attempted to cast and which errors we saw, as well as the raw response and, of course, options. For this adapter, we will only need params, errors and raw response.
defmodule OllamaAdapterRetryPrompt do
  def retry_prompt(params, _resp_params, errors, response, _opts) do
    message = Map.fetch!(response, "message")

    do_better = [
      message,
      %{
        role: "user",
        content: InstructorLite.Prompt.validation_failed(errors)
      }
    ]

    Map.update(params, :messages, do_better, fn msgs -> msgs ++ do_better end)
  end
end

retry_prompt = OllamaAdapterRetryPrompt.retry_prompt(prompt, nil, errors, response, [])
%{
  messages: [
    %{
      role: "system",
      content: "You're called by an Elixir application through the InstructorLite library. Your task is to understand what the application wants you to do and respond with JSON output that matches the schema. The output will be validated by the application against an Ecto schema and potentially some custom rules. You may be asked to adjust your response if it doesn't pass validation. "
    },
    %{role: "user", content: "Who was the first president of the united states?"},
    %{"content" => "{\n  \"name\": \"George_Washington\"\n}\n\n  ", "role" => "assistant"},
    %{
      role: "user",
      content: "The response did not pass validation. Please try again and fix the following validation errors:\n\nname - is invalid\n"
    }
  ],
  stream: false,
  format: %{
    type: "object",
    title: "root",
    required: [:name],
    additionalProperties: false,
    properties: %{name: %{type: "string"}}
  },
  model: "deepseek-r1:8b"
}
This retry prompt can now be used for a send_request/2 call. We won't do it though, to avoid gaslighting the model by suggesting its answer was incorrect.
Optional Callbacks
If you plan to use your adapter for non-structured output through InstructorLite.ask/2 function, you'll need to also implement an optional InstructorLite.Adapter.find_output/2 callback. It's role is simply to find output in the response. In our case, the callback is exactly the same as parse_response/2, with the only difference is that it doesn't need to parse JSON.
defmodule OllamaAdapterFindOutput do
  def find_output(response, _opts) do
    case response do
      %{"message" => %{"content" => output}} ->
        {:ok, output}

      other ->
        {:error, :unexpected_response, other}
    end
  end
end

{:ok, params} = OllamaAdapterFindOutput.find_output(response, [])
{:ok, "{\n  \"name\": \"George_Washington\"\n}\n\n  "}
Tying It All Together
Now we can put all these callbacks into a single module, confess to the compiler that our intention is to implement a behavior, and let the InstructorLite main interface handle all the logistics.
defmodule OllamaAdapter do
  @behaviour InstructorLite.Adapter

  @impl InstructorLite.Adapter
  def send_request(params, options) do
    url = options |> Keyword.get(:adapter_context, []) |> Keyword.fetch!(:url)

    case Req.post(url, json: params, receive_timeout: 120_000) do
      {:ok, %{status: 200, body: body}} -> {:ok, body}
      {:ok, response} -> {:error, response}
      {:error, reason} -> {:error, reason}
    end
  end

  @impl InstructorLite.Adapter
  def initial_prompt(params, opts) do
    sys_message = [
      %{
        role: "system",
        content: InstructorLite.Prompt.prompt(opts)
      }
    ]

    params
    |> Map.put_new(:model, "deepseek-r1:8b")
    |> Map.put(:stream, false)
    |> Map.update(:messages, sys_message, fn msgs -> sys_message ++ msgs end)
    |> Map.put(:format, Keyword.fetch!(opts, :json_schema))
  end

  @impl InstructorLite.Adapter
  def parse_response(response, opts) do
    with {:ok, json} <- find_output(response, opts) do
      InstructorLite.JSON.decode(json)
    end
  end

  @impl InstructorLite.Adapter
  def find_output(response, _opts) do
    case response do
      %{"message" => %{"content" => output}} ->
        {:ok, output}

      other ->
        {:error, :unexpected_response, other}
    end
  end

  @impl InstructorLite.Adapter
  def retry_prompt(params, _resp_params, errors, response, _opts) do
    message = Map.fetch!(response, "message")

    do_better = [
      message,
      %{
        role: "user",
        content: InstructorLite.Prompt.validation_failed(errors)
      }
    ]

    Map.update(params, :messages, do_better, fn msgs -> msgs ++ do_better end)
  end
end

InstructorLite.instruct(%{
    messages: [
      %{role: "user", content: "Dr. John Doe is forty two"}
    ],
  },
  adapter: OllamaAdapter,
  notes: "Trim down all people's titles",
  response_model: %{name: :string, age: :integer},
  adapter_context: [
    url: "http://localhost:11434/api/chat"
  ]
)
{:ok, %{name: "John Doe", age: 42}}
Note how we used find_output/2 in parse_response/2 to DRY our code a little.
Let's now try ask:
InstructorLite.ask(%{
    model: "deepseek-r1:8b",
    stream: false,
    think: false,
    messages: [
      %{role: "user", content: "Cite me the greatest opening line in the history of cyberpunk. No yapping, just the line."}
    ],
  },
  adapter: OllamaAdapter,
  adapter_context: [
    url: "http://localhost:11434/api/chat"
  ]
)
{:ok, "\" All secrets are best kept cool.\" - Neuromancer"}


  

    OpenAI Advanced Features

Mix.install(
  [
    {:instructor_lite, "~> 1.0"},
    {:req, "~> 0.5"},
    {:kino, "~> 0.16"}
  ]
)
Motivation
OpenAI has introduced a lot of features since InstructorLite was first released. Let's explore some of them and see if they can be of any help.
Setup
In order to run code in this notebook, you need to add your OpenAI API key as an OPENAI_KEY Livebook secret. It will then be accessible through an environment variable.
secret_key = System.fetch_env!("LB_OPENAI_KEY")
:ok
:ok
Image Input
[image: ]
file = Kino.FS.file_path("shopify-screenshot.png") |> File.read!()
base64_image = "data:image/png;base64," <> Base.encode64(file)

defmodule Product do
  use Ecto.Schema

  @primary_key false
  embedded_schema do
    field(:name, :string)
    field(:price, :decimal)
    field(:currency, Ecto.Enum, values: [:usd, :gbp, :eur, :cny])
    field(:color, :string)
  end
end

{:ok, result} =
  InstructorLite.instruct(%{
      model: "gpt-4o-mini",
      input: [
        %{
          role: "user",
          content: [
            %{type: "input_text", text: "What is the product details of the following image?"},
            %{type: "input_image", image_url: base64_image}
          ]
        }
      ]
    },
    response_model: Product,
    adapter_context: [api_key: secret_key]
  )

result
%Product{
  name: "Thomas Wooden Railway Thomas the Tank Engine",
  price: Decimal.new("33.0"),
  currency: :usd,
  color: "blue"
}
Built-in Tool Use
OpenAI supports a number of built-in tools, such as web search!
defmodule Package do
  use Ecto.Schema

  @primary_key false
  embedded_schema do
    field(:name, :string)
    field(:github_link, :string)
    field(:latest_version, :string)
  end
end

{:ok, result} =
  InstructorLite.instruct(%{
      model: "gpt-4o-mini",
      tools: [%{type: "web_search_preview"}],
      input: "We want to know about: InstructorLite Hex package"
    },
    response_model: Package,
    adapter_context: [api_key: secret_key]
  )

result
%Package{
  name: "InstructorLite",
  github_link: "https://github.com/martosaur/instructor_lite",
  latest_version: "1.0.0"
}
Reasoning
Reasoning models are powerful, but ultimately, reasoning doesn't affect structured output in any way. However, they can be very useful to keep track of the reasoning behind the output. InstructorLite.instruct/2 does not give you access to the raw output, but you can use lower-level functions to sidestep this.
require Logger

adventure_description = """
Something strange is happening to your hometown of Willowshore! Nestled on the
banks of a river winding through the legendary Specterwood in Tian Xia’s haunted
land of Shenmen, the people of Willowshore are no strangers to supernatural
threat, but the danger that comes to town on the first day of summer is unlike
anything you’ve ever seen before. Over the four seasons to come, you and your
fellow home-grown heroes must face evil spirits, sinister fiends, and
frightening curses, lest the town of Willowshore succumb to the Season of
Ghosts!
"""

opts = [
  response_model: %{toponyms: {:array, :string}},
  adapter_context: [api_key: secret_key]
]

params = InstructorLite.prepare_prompt(%{
      model: "o4-mini",
      reasoning: %{effort: "medium", summary: "auto"},
      input: [
        %{role: "system", content: "Here's an adventure description, please extract all toponyms"},
        %{role: "user", content: adventure_description}
      ]
  }, opts)

{:ok, response} = InstructorLite.Adapters.OpenAI.send_request(params, opts)
{:ok, result} = InstructorLite.consume_response(response, params, opts)

for %{"summary" => summaries} <- response["output"] do
  for %{"type" => "summary_text", "text" => text} <- summaries do
    Logger.info(text)
  end
end

result

13:34:05.078 [info] **Extracting toponyms**

The user is interested in extracting all toponyms from a prompt about Willowshore. I’ll identify the place names, which include: Willowshore, Specterwood, Tian Xia, and Shenmen. Event names, like "the Season of Ghosts," aren't toponyms. The phrase "the banks of a river" doesn't name the river either. 

I’ll ensure to include only unique entries, ultimately returning this list in a structured format as JSON: {"toponyms":["Willowshore","Specterwood","Tian Xia","Shenmen"]}.

%{toponyms: ["Willowshore", "Specterwood", "Tian Xia", "Shenmen"]}

Main building blocks of InstructorLite.
Key Concepts
Structured prompting can be quite different depending on the LLM and InstructorLite does only the bare minimum to abstract this complexity. This means the usage can be quite different depending on the adapter you're using, so make sure to consult adapter documentation to learn the details.
There are two key arguments used throughout this module. Understanding what they are will make your life a lot easier.
	params - is an adapter-specific map, that contain values eventually sent to the LLM. More simply, this is the body that will be posted to the API endpoint. You prompt, model name, optional parameters like temperature all likely belong here.
	opts - is a list of options that shape behavior of InstructorLite itself. Options may include things like which schema to cast response to, http client to use, api key, optional headers, http timeout, etc.

Shared options
Most functions in this module accept a list of options.
	:response_model - Required. A module implementing InstructorLite.Instruction behaviour, Ecto schema or schemaless Ecto definition

	:max_retries (non_neg_integer/0) - How many additional attempts to make if changeset validation fails. The default value is 0.

	:validate_changeset (function of arity 2) - Override function to be called instead of response_model.validate_changeset/2 callback

	:notes (String.t/0) - Additional notes about the schema that might be used by an adapter

	:json_schema (map/0) - JSON schema to use instead of calling response_model.json_schema/0 callback or generating it at runtime using InstructorLite.JSONSchema module

	:adapter (atom/0) - A module implementing InstructorLite.Adapter behaviour. The default value is InstructorLite.Adapters.OpenAI.

	:adapter_context (term/0) - Options used by adapter callbacks. See adapter docs for schema.

	:extra (term/0) - Any arbitrary term for ad-hoc usage. For example, in InstructorLite.Instruction.validate_changeset/2 callback

        ask_opts()

      


        Ask options are a subset of all options, used by the ask/2 function.



    


    
      
        opts()

      


        Options passed to instructor functions.



    





  
    Functions
  


    
      
        ask(params, opts)

      


        Perform a simple request with a non-structured response.



    


    
      
        consume_response(response, params, opts)

      


        Triage raw LLM response



    


    
      
        instruct(params, opts)

      


        Perform instruction session from start to finish.



    


    
      
        prepare_prompt(params, opts)

      


        Prepare prompt that can be later sent to LLM



    





      


      
        Types


        


  
    
      
    
    
      ask_opts()



        
          
        

    

  


  

      

          @type ask_opts() :: [adapter: atom(), adapter_context: term(), extra: term()]


      


Ask options are a subset of all options, used by the ask/2 function.

  



  
    
      
    
    
      opts()



        
          
        

    

  


  

      

          @type opts() :: [
  response_model: atom() | Ecto.Changeset.types(),
  max_retries: non_neg_integer(),
  validate_changeset: (Ecto.Changeset.t(), opts() -> Ecto.Changeset.t()),
  notes: String.t(),
  json_schema: map(),
  adapter: atom(),
  adapter_context: term(),
  extra: term()
]


      


Options passed to instructor functions.

  


        

      

      
        Functions


        


  
    
      
    
    
      ask(params, opts)


        (since 1.1.0)


        
          
        

    

  


  

      

          @spec ask(InstructorLite.Adapter.params(), ask_opts()) ::
  {:ok, String.t()} | {:error, any()} | {:error, atom(), any()}


      


Perform a simple request with a non-structured response.
This function is useful when you already have InstructorLite setup in the
project and need to get simple text output.
Examples
Basic Example
OpenAI
iex> InstructorLite.ask(%{
    model: "gpt-5-mini-2025-08-07",
    input: [
      %{role: "user", content: "Cite me the greatest opening line in the history of cyberpunk."}
    ]
  },
  adapter: InstructorLite.Adapters.OpenAI,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :openai_key)]
)
{:ok, "The sky above the port was the color of television, tuned to a dead channel."}
Anthropic
iex> InstructorLite.ask(%{
    messages: [
      %{role: "user", content: "Cite me the greatest opening line in the history of cyberpunk."}
    ],
    max_tokens: 100,
    model: "claude-sonnet-4-20250514"
  },
  adapter: InstructorLite.Adapters.Anthropic,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :anthropic_key)]
)
{:ok, "The sky above the port was the color of television, tuned to a dead channel."}
Gemini
iex> InstructorLite.ask(%{
    contents: [
      %{
        role: "user",
        parts: [%{text: "Cite me the greatest opening line in the history of cyberpunk."}]
      }
    ]
  },
  adapter: InstructorLite.Adapters.Gemini,
  adapter_context: [
    api_key: Application.fetch_env!(:instructor_lite, :gemini_key)
  ]
)
{:ok, "The sky above the port was the color of a bruise."} # 🫠
Grok
iex> InstructorLite.ask(%{
    model: "grok-3-latest",
    messages: [
      %{
        role: "user",
        content: "Cite me the greatest opening line in the history of cyberpunk."
      }
    ]
  },
  adapter: InstructorLite.Adapters.ChatCompletionsCompatible,
  adapter_context: [
    url: "https://api.x.ai/v1/chat/completions",
    api_key: Application.fetch_env!(:instructor_lite, :grok_key)
  ]
)
{:ok, "The sky above the port was the color of television, tuned to a dead channel."}

  



  
    
      
    
    
      consume_response(response, params, opts)



        
          
        

    

  


  

      

          @spec consume_response(
  InstructorLite.Adapter.response(),
  InstructorLite.Adapter.params(),
  opts()
) ::
  {:ok, Ecto.Schema.t()}
  | {:error, Ecto.Changeset.t(), InstructorLite.Adapter.params()}
  | {:error, any()}
  | {:error, reason :: atom(), any()}


      


Triage raw LLM response
Attempts to cast raw response from InstructorLite.Adapter.send_request/2 and either returns an object or an invalid changeset with new prompt that can be used for a retry.
This function will call InstructorLite.Instruction.validate_changeset/2 callback, unless validate_changeset option is overridden in opts.

  



  
    
      
    
    
      instruct(params, opts)



        
          
        

    

  


  

      

          @spec instruct(InstructorLite.Adapter.params(), opts()) ::
  {:ok, Ecto.Schema.t()}
  | {:error, Ecto.Changeset.t()}
  | {:error, any()}
  | {:error, atom(), any()}


      


Perform instruction session from start to finish.
This function glues together all other functions and adds retries on top.
Examples
Basic Example
OpenAI
iex> InstructorLite.instruct(%{
    input: [
      %{role: "user", content: "John Doe is fourty two years old"}
    ]
  },
  response_model: %{name: :string, age: :integer},
  adapter: InstructorLite.Adapters.OpenAI,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :openai_key)]
)
{:ok, %{name: "John Doe", age: 42}}
Anthropic
iex> InstructorLite.instruct(%{
    messages: [
      %{role: "user", content: "John Doe is fourty two years old"}
    ]
  },
  response_model: %{name: :string, age: :integer},
  adapter: InstructorLite.Adapters.Anthropic,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :anthropic_key)]
)
{:ok, %{name: "John Doe", age: 42}}
Llamacpp
iex> InstructorLite.instruct(%{
    prompt: "John Doe is fourty two years old"
  },
  response_model: %{name: :string, age: :integer},
  adapter: InstructorLite.Adapters.Llamacpp,
  adapter_context: [url: Application.fetch_env!(:instructor_lite, :llamacpp_url)]
)
{:ok, %{name: "John Doe", age: 42}}
Gemini
iex> InstructorLite.instruct(%{
    contents: [
      %{
        role: "user",
        parts: [%{text: "John Doe is fourty two years old"}]
      }
    ]
  },
  response_model: %{name: :string, age: :integer},
  json_schema: %{
    type: "object",
    required: [:age, :name],
    properties: %{name: %{type: "string"}, age: %{type: "integer"}}
  },
  adapter: InstructorLite.Adapters.Gemini,
  adapter_context: [
    api_key: Application.fetch_env!(:instructor_lite, :gemini_key)
  ]
)
{:ok, %{name: "John Doe", age: 42}}
Using max_retries
defmodule Rhymes do
  use Ecto.Schema
  use InstructorLite.Instruction
  
  @primary_key false
  embedded_schema do
    field(:word, :string)
    field(:rhymes, {:array, :string})
  end
  
  @impl true
  def validate_changeset(changeset, _opts) do
    Ecto.Changeset.validate_length(changeset, :rhymes, is: 3)
  end
end

InstructorLite.instruct(%{
    input: [
      %{role: "user", content: "Take the last word from the following line and add some rhymes to it
Even though you broke my heart"}
    ]
  },
  response_model: Rhymes,
  max_retries: 1,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :openai_key)]
)
{:ok, %Rhymes{word: "heart", rhymes: ["part", "start", "dart"]}}

  



  
    
      
    
    
      prepare_prompt(params, opts)



        
          
        

    

  


  

      

          @spec prepare_prompt(InstructorLite.Adapter.params(), opts()) ::
  InstructorLite.Adapter.params()


      


Prepare prompt that can be later sent to LLM
The prompt is added to params, so you need to cooperate with the adapter to know what you can provide there.
The function will call InstructorLite.Instruction.notes/0 and InstructorLite.Instruction.json_schema/0 callbacks for response_model. Both can be overriden with corresponding options in opts.

  


        

      


  

    
InstructorLite.JSONSchema 
    



      
Helper module to generate JSON Schema based on Ecto schema.
JSON Schema comes in many flavors and different LLMs have different limitations. Currently, this module aims to implement a schema suitable for OpenAI structured outputs. This type of JSON schema may not be optimal or compatible with other models. Therefore, it's recommended to use this module as a starting point to generate a schema during development. You can then manually refine the schema and either implement it in the InstructorLite.Instruction.json_schema/0 callback or pass it as an option.
Warning
For the reasons described above, neither backward compatibility nor compatibility with all built-in adapters are goals of this module.

      


      
        Summary


  
    Functions
  


    
      
        from_ecto_schema(ecto_schema)

      


        Generates a JSON Schema from an Ecto schema.



    





      


      
        Functions


        


  
    
      
    
    
      from_ecto_schema(ecto_schema)



        
          
        

    

  


  

Generates a JSON Schema from an Ecto schema.

  


        

      


  

    
InstructorLite.Adapter behaviour
    



      
Behaviour for implementing adapter modules.
The role of an adapter module is to encapsulate all logic for a particular LLM, which can be quite specific. As a result, most of the details live in adapter modules and main InstructorLite interface is very broad.
Implement your own!
While built-in adapters are fairly flexible, users are encouraged to write their own adapters to establish a better control over prompt building, http clients, etc.

      


      
        Summary


  
    Types
  


    
      
        params()

      


        Map of adapter-specific values, such as messages, prompt, model name, or temperature. These parameters are typically sent to the LLM in request body.



    


    
      
        parsed_response()

      


        Parsed response content that can be cast to a changeset.



    


    
      
        response()

      


        Raw content of a successful response.



    





  
    Callbacks
  


    
      
        find_output(response, opts)

      


        Find text output in the response.



    


    
      
        initial_prompt(params, opts)

      


        Update params with model-specific prompt.



    


    
      
        parse_response(response, opts)

      


        Parse API response.



    


    
      
        retry_prompt(params, parsed_response, errors, response, opts)

      


        Update params with model-specific prompt for a retry. This usually involves appending errors from a changeset.



    


    
      
        send_request(params, opts)

      


        Make request to model API.



    





      


      
        Types


        


  
    
      
    
    
      params()



        
          
        

    

  


  

      

          @type params() :: map()


      


Map of adapter-specific values, such as messages, prompt, model name, or temperature. These parameters are typically sent to the LLM in request body.

  



  
    
      
    
    
      parsed_response()



        
          
        

    

  


  

      

          @type parsed_response() :: map()


      


Parsed response content that can be cast to a changeset.

  



  
    
      
    
    
      response()



        
          
        

    

  


  

      

          @type response() :: any()


      


Raw content of a successful response.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      find_output(response, opts)


        (since 1.1.0)

        (optional)


        
          
        

    

  


  

      

          @callback find_output(response(), InstructorLite.opts()) ::
  {:ok, String.t()} | {:error, any()} | {:error, reason :: atom(), any()}


      


Find text output in the response.
Similar to parse_response/2, but this callback assumes a simple plain text
response. Used in InstructorLite.ask/2 function. 

  



  
    
      
    
    
      initial_prompt(params, opts)



        
          
        

    

  


  

      

          @callback initial_prompt(params(), InstructorLite.opts()) :: params()


      


Update params with model-specific prompt.

  



  
    
      
    
    
      parse_response(response, opts)



        
          
        

    

  


  

      

          @callback parse_response(response(), InstructorLite.opts()) ::
  {:ok, parsed_response()} | {:error, any()} | {:error, reason :: atom(), any()}


      


Parse API response.
On success, it returns an ok tuple with parsed json object ready to be cast to a changeset.
On error, it may return a 3-element error tuple with error reason. In the worst-case scenario, it returns the original input wrapped in an error tuple. 

  



  
    
      
    
    
      retry_prompt(params, parsed_response, errors, response, opts)



        
          
        

    

  


  

      

          @callback retry_prompt(
  params(),
  parsed_response(),
  errors :: String.t(),
  response(),
  InstructorLite.opts()
) :: params()


      


Update params with model-specific prompt for a retry. This usually involves appending errors from a changeset.

  



  
    
      
    
    
      send_request(params, opts)



        
          
        

    

  


  

      

          @callback send_request(params(), InstructorLite.opts()) ::
  {:ok, response()} | {:error, any()}


      


Make request to model API.

  


        

      


  

    
InstructorLite.Instruction behaviour
    



      
use InstructorLite.Instruction is a way to make your Ecto schema into an Instruction, which provides additional callbacks used by InstructorLite.
Example
defmodule SpamPrediction do
  use Ecto.Schema
  use InstructorLite.Instruction

  @notes """
  Field Descriptions:
  - class: Whether or not the email is spam.
  - reason: A short, less than 10-word rationalization for the classification.
  - score: A confidence score between 0.0 and 1.0 for the classification.
  """
  @primary_key false
  embedded_schema do
    field(:class, Ecto.Enum, values: [:spam, :not_spam])
    field(:reason, :string)
    field(:score, :float)
  end

  @impl InstructorLite.Instruction
  def validate_changeset(changeset, _opts) do
    Ecto.Changeset.validate_number(changeset, :score,
      greater_than_or_equal_to: 0.0,
      less_than_or_equal_to: 1.0
    )
  end
end
use InstructorLite.Instruction
When you use InstructorLite.Instruction, the Instruction module will set @behaviour InstructorLite.Instruction, and define default implementations of notes/0 and json_schema/0 callbacks.

      


      
        Summary


  
    Callbacks
  


    
      
        json_schema()

      


        Defines JSON schema for the instruction.



    


    
      
        notes()

      


        Defines an optional free-form description of the schema.



    


    
      
        validate_changeset(t, opts)

      


        Called by InstructorLite.consume_response/3 as part of changeset validation.



    





      


      
        Callbacks


        


  
    
      
    
    
      json_schema()



        
          
        

    

  


  

      

          @callback json_schema() :: map()


      


Defines JSON schema for the instruction.
By default, InstructorLite.JSONSchema.from_ecto_schema/1 is called at runtime every time InstructorLite needs to convert an Ecto schema to JSON schema. However, you can bake your own JSON schema into the json_schema/0 callback to eliminate the need to do it on every call.
Tip
Take advantage of this callback! Most JSON schemas are known ahead of time, so there is no need to constantly build them at runtime. In addition, InstructorLite.JSONSchema module aims to generate one-size-fits-all schema, so it's very unlikely to take full advantage of JSON capabilities of your LLM of choice.   

  



  
    
      
    
    
      notes()



        
          
        

    

  


  

      

          @callback notes() :: String.t() | nil


      


Defines an optional free-form description of the schema.
You can define a @notes attribute or notes/0 callback to provide an additional free-form description to the schema. This description will be passed to the LLM together with the schema definition.

  



  
    
      
    
    
      validate_changeset(t, opts)


        (optional)


        
          
        

    

  


  

      

          @callback validate_changeset(Ecto.Changeset.t(), InstructorLite.opts()) ::
  Ecto.Changeset.t()


      


Called by InstructorLite.consume_response/3 as part of changeset validation.
It has full access to all opts. If you need to pass an arbitrary term to this callback, use the extra key.
Example
# Let's play a guessing game!
defmodule CoinGuess do
  use Ecto.Schema
  use InstructorLite.Instruction

  @primary_key false
  embedded_schema do
    field(:guess, Ecto.Enum, values: [:heads, :tails])
  end

  @impl InstructorLite.Instruction
  def validate_changeset(cs, opts) do
    target = Keyword.fetch!(opts, :extra)

    case Ecto.Changeset.fetch_field!(cs, :guess) do
      ^target -> cs
      _ -> Ecto.Changeset.add_error(cs, :guess, "Wrong! Try again")
    end
  end
end

  


        

      


  

    
InstructorLite.Adapters.Anthropic 
    



      
Anthropic adapter.
This adapter is implemented using the Messages
API and structured
outputs.
For older models that don't support structured outputs, function
calling is
used.
Params
params argument should be shaped as a Create message request body.
Example
InstructorLite.instruct(%{
    messages: [%{role: "user", content: "John is 25yo"}],
    model: "claude-sonnet-4-5",
    metadata: %{user_id: "3125"}
  },
  response_model: %{name: :string, age: :integer},
  adapter: InstructorLite.Adapters.Anthropic,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :anthropic_key)]
)
{:ok, %{name: "John", age: 25}}

      


      
        Summary


  
    Functions
  


    
      
        find_output(response, opts)

      


        Parse API response in search of plain text output.



    


    
      
        initial_prompt(params, opts)

      


        Updates params with prompt based on json_schema and notes.



    


    
      
        parse_response(response, opts)

      


        Parse API response.



    


    
      
        retry_prompt(params, resp_params, errors, response, opts)

      


        Updates params with prompt for retrying a request.



    


    
      
        send_request(params, opts)

      


        Make request to Anthropic API



    





      


      
        Functions


        


  
    
      
    
    
      find_output(response, opts)



        
          
        

    

  


  

Parse API response in search of plain text output.
Can return:
	{:ok, text_output} on success.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      initial_prompt(params, opts)



        
          
        

    

  


  

Updates params with prompt based on json_schema and notes.
Also specifies default claude-haiku-4-5 model and 1024 max_tokens if not provided by a user.

  



  
    
      
    
    
      parse_response(response, opts)



        
          
        

    

  


  

Parse API response.
Can return:
	{:ok, parsed_object} on success.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      retry_prompt(params, resp_params, errors, response, opts)



        
          
        

    

  


  

Updates params with prompt for retrying a request.
The error is represented as a user message or erroneous tool_result for
older models.

  



  
    
      
    
    
      send_request(params, opts)



        
          
        

    

  


  

Make request to Anthropic API
Options
	:api_key (String.t/0) - Required. Anthropic API key

	:http_client (atom/0) - Any module that follows Req.post/2 interface The default value is Req.

	:http_options (keyword/0) - Options passed to http_client.post/2 The default value is [receive_timeout: 60000].

	:url (String.t/0) - API endpoint to use for sending requests The default value is "https://api.anthropic.com/v1/messages".

	:version (String.t/0) - Anthropic API version The default value is "2023-06-01".



  


        

      


  

    
InstructorLite.Adapters.ChatCompletionsCompatible 
    



      
Adapter for Chat Completions-compatible API endpoints, such as
OpenAI,
Grok or
Gemini.
This adapter uses structured
outputs.
Params
params argument should be shaped as a Create chat completion request body.
Example
InstructorLite.instruct(%{
    messages: [%{role: "user", content: "John is 25yo"}],
    model: "gpt-4o-mini",
    service_tier: "default"
  },
  response_model: %{name: :string, age: :integer},
  adapter: InstructorLite.Adapters.ChatCompletionsCompatible,
  adapter_context: [
    api_key: Application.fetch_env!(:instructor_lite, :openai_key),
    url: "https://api.openai.com/v1/chat/completions"
  ]
)
{:ok, %{name: "John", age: 25}}

      


      
        Summary


  
    Functions
  


    
      
        find_output(response, opts)

      


        Parse chat completion endpoint response in search of plain text output.



    


    
      
        initial_prompt(params, opts)

      


        Updates params with prompt based on json_schema and notes.



    


    
      
        parse_response(response, opts)

      


        Parse chat completion endpoint response.



    


    
      
        retry_prompt(params, resp_params, errors, response, opts)

      


        Updates params with prompt for retrying a request.



    


    
      
        send_request(params, opts)

      


        Make request to API.



    





      


      
        Functions


        


  
    
      
    
    
      find_output(response, opts)



        
          
        

    

  


  

Parse chat completion endpoint response in search of plain text output.
Can return:
	{:ok, text_output} on success.
	{:error, :refusal, reason} on refusal.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      initial_prompt(params, opts)



        
          
        

    

  


  

Updates params with prompt based on json_schema and notes.
Also specifies default gpt-4o-mini model if not provided by a user. 

  



  
    
      
    
    
      parse_response(response, opts)



        
          
        

    

  


  

Parse chat completion endpoint response.
Can return:
	{:ok, parsed_json} on success.
	{:error, :refusal, reason} on refusal.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      retry_prompt(params, resp_params, errors, response, opts)



        
          
        

    

  


  

Updates params with prompt for retrying a request.

  



  
    
      
    
    
      send_request(params, opts)



        
          
        

    

  


  

Make request to API.
Options
	:api_key (String.t/0) - Required. API key

	:http_client (atom/0) - Any module that follows Req.post/2 interface The default value is Req.

	:http_options (keyword/0) - Options passed to http_client.post/2 The default value is [receive_timeout: 60000].

	:url (String.t/0) - API endpoint to use for sending requests The default value is "https://api.openai.com/v1/chat/completions".



  


        

      


  

    
InstructorLite.Adapters.Gemini 
    



      
Gemini adapter.
This adapter is implemented using Text generation endpoint configured for structured output
Params
params argument should be shaped as a models.GenerateBody request body
Example
InstructorLite.instruct(
  %{contents: [%{role: "user", parts: [%{text: "John is 25yo"}]}]},
  response_model: %{name: :string, age: :integer},
  json_schema: %{
    type: "object",
    required: [:age, :name],
    properties: %{name: %{type: "string"}, age: %{type: "integer"}}
  },
  adapter: InstructorLite.Adapters.Gemini,
  adapter_context: [
    model: "gemini-1.5-flash-8b",
    api_key: Application.fetch_env!(:instructor_lite, :gemini_key)
  ]
)
{:ok, %{name: "John", age: 25}}
Specifying model
Note how, unlike other adapters, the Gemini adapter expects model under adapter_context. 
JSON Schema
The adapter uses Gemini's responseJsonSchema
field which accepts standard JSON Schema, including features like $ref, $defs,
title, and additionalProperties that Gemini's older responseSchema field does not support.
Chat Completions Compatible
If any of the limitations above are important to you, know that Gemini also provides a chat completion endpoint. You can use it with the InstructorLite.Adapters.ChatCompletionsCompatible adapter.

      


      
        Summary


  
    Functions
  


    
      
        find_output(response, opts)

      


        Parse text generation endpoint response in search of plain text output.



    


    
      
        initial_prompt(params, opts)

      


        Puts systemInstruction and updates generationConfig in params with prompt based on json_schema and notes.



    


    
      
        parse_response(response, opts)

      


        Parse text generation endpoint response.



    


    
      
        retry_prompt(params, resp_params, errors, response, opts)

      


        Updates params with prompt for retrying a request.



    


    
      
        send_request(params, opts)

      


        Make request to Gemini API



    





      


      
        Functions


        


  
    
      
    
    
      find_output(response, opts)



        
          
        

    

  


  

Parse text generation endpoint response in search of plain text output.
Can return:
	{:ok, text_output} on success.
	{:error, :refusal, prompt_feedback} if request was blocked.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      initial_prompt(params, opts)



        
          
        

    

  


  

Puts systemInstruction and updates generationConfig in params with prompt based on json_schema and notes.

  



  
    
      
    
    
      parse_response(response, opts)



        
          
        

    

  


  

Parse text generation endpoint response.
Can return:
	{:ok, parsed_json} on success.
	{:error, :refusal, prompt_feedback} if request was blocked.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      retry_prompt(params, resp_params, errors, response, opts)



        
          
        

    

  


  

Updates params with prompt for retrying a request.

  



  
    
      
    
    
      send_request(params, opts)



        
          
        

    

  


  

Make request to Gemini API
Options
	:api_key (String.t/0) - Required. Gemini API key

	:http_client (atom/0) - Any module that follows Req.post/2 interface The default value is Req.

	:http_options (keyword/0) - Options passed to http_client.post/2 The default value is [receive_timeout: 60000].

	:url (String.t/0) - API endpoint to use for sending requests The default value is "https://generativelanguage.googleapis.com/v1beta/models/{model}:generateContent".

	:model (String.t/0) - Gemini model The default value is "gemini-3.5-flash-lite".



  


        

      


  

    
InstructorLite.Adapters.Llamacpp 
    



      
LLaMA.cpp HTTP Server adapter.
This adapter is implemented using llama-specific completion endpoint.
Params
params argument should be shaped as a completion request body
Example
InstructorLite.instruct(%{
    prompt: "John is 25yo",
    temperature: 0.8
  },
  response_model: %{name: :string, age: :integer},
  adapter: InstructorLite.Adapters.Llamacpp,
  adapter_context: [url: "http://localhost:8000/completion"]
)
{:ok, %{name: "John", age: 25}}

      


      
        Summary


  
    Functions
  


    
      
        find_output(response, opts)

      


        Parse API response in search of plain text output.



    


    
      
        initial_prompt(params, opts)

      


        Updates params with prompt based on json_schema and notes.



    


    
      
        parse_response(response, opts)

      


        Parse API response.



    


    
      
        retry_prompt(params, resp_params, errors, response, opts)

      


        Updates params with prompt for retrying a request.



    


    
      
        send_request(params, opts)

      


        Make request to llamacpp HTTP server.



    





      


      
        Functions


        


  
    
      
    
    
      find_output(response, opts)



        
          
        

    

  


  

Parse API response in search of plain text output.
Can return:
	{:ok, text_output} on success.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      initial_prompt(params, opts)



        
          
        

    

  


  

Updates params with prompt based on json_schema and notes.
It uses json_schema and system_prompt request parameters.

  



  
    
      
    
    
      parse_response(response, opts)



        
          
        

    

  


  

Parse API response.
Can return:
	{:ok, parsed_json} on success.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      retry_prompt(params, resp_params, errors, response, opts)



        
          
        

    

  


  

Updates params with prompt for retrying a request.

  



  
    
      
    
    
      send_request(params, opts)



        
          
        

    

  


  

Make request to llamacpp HTTP server.
Options
	:http_client (atom/0) - Any module that follows Req.post/2 interface The default value is Req.

	:http_options (keyword/0) - Options passed to http_client.post/2 The default value is [receive_timeout: 60000].

	:url (String.t/0) - Required. API endpoint to use, for example http://localhost:8000/completion



  


        

      


  

    
InstructorLite.Adapters.OpenAI 
    



      
OpenAI adapter. 
This adapter is implemented using
responses endpoint
and structured
outputs.
Params
params argument should be shaped as a Create model response request
body.
Example
InstructorLite.instruct(%{
    input: [%{role: "user", content: "John is 25yo"}],
    model: "gpt-4o-mini",
    service_tier: "default"
  },
  response_model: %{name: :string, age: :integer},
  adapter: InstructorLite.Adapters.OpenAI,
  adapter_context: [api_key: Application.fetch_env!(:instructor_lite, :openai_key)]
)
{:ok, %{name: "John", age: 25}}

      


      
        Summary


  
    Functions
  


    
      
        find_output(response, opts)

      


        Parse API response in search of plain text output.



    


    
      
        initial_prompt(params, opts)

      


        Updates params with prompt based on json_schema and notes.



    


    
      
        parse_response(response, opts)

      


        Parse chat completion endpoint response.



    


    
      
        retry_prompt(params, resp_params, errors, response, opts)

      


        Updates params with prompt for retrying a request.



    


    
      
        send_request(params, opts)

      


        Make request to OpenAI API.



    





      


      
        Functions


        


  
    
      
    
    
      find_output(response, opts)



        
          
        

    

  


  

Parse API response in search of plain text output.
Can return:
	{:ok, text_output} on success.
	{:error, :refusal, reason} on refusal.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      initial_prompt(params, opts)



        
          
        

    

  


  

Updates params with prompt based on json_schema and notes.
It uses instructions parameter for system prompt.
Also specifies default gpt-4o-mini model if not provided by a user. 

  



  
    
      
    
    
      parse_response(response, opts)



        
          
        

    

  


  

Parse chat completion endpoint response.
Can return:
	{:ok, parsed_json} on success.
	{:error, :refusal, reason} on refusal.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      retry_prompt(params, resp_params, errors, response, opts)



        
          
        

    

  


  

Updates params with prompt for retrying a request.
If the initial request was made with conversation state (enabled by
default), it will drop previous chat messages from the request and specify
previous_response_id instead. If conversation state is disabled, it will
append new messages to the previous input the same way chat completions-based
adapters do.

  



  
    
      
    
    
      send_request(params, opts)



        
          
        

    

  


  

Make request to OpenAI API.
Options
	:api_key (String.t/0) - Required. API key

	:http_client (atom/0) - Any module that follows Req.post/2 interface The default value is Req.

	:http_options (keyword/0) - Options passed to http_client.post/2 The default value is [receive_timeout: 60000].

	:url (String.t/0) - API endpoint to use for sending requests The default value is "https://api.openai.com/v1/responses".



  


        

      


  

    
InstructorLite.Adapters.ResponsesCompatible 
    



      
Adapter for Responses-compatible API endpoints, such as
OpenAI,
Grok.
This adapter uses structured
outputs.
Params
params argument should be shaped as a Create model response request
body.
Example
InstructorLite.instruct(%{
    input: [%{role: "user", content: "John is 25yo"}],
    model: "gpt-5.6-luna",
    service_tier: "default"
  },
  response_model: %{name: :string, age: :integer},
  adapter: InstructorLite.Adapters.ResponsesCompatible,
  adapter_context: [
    api_key: Application.fetch_env!(:instructor_lite, :openai_key),
    url: "https://api.openai.com/v1/responses"
  ]
)
{:ok, %{name: "John", age: 25}}

      


      
        Summary


  
    Functions
  


    
      
        find_output(response, opts)

      


        Parse API response in search of plain text output.



    


    
      
        initial_prompt(params, opts)

      


        Updates params with prompt based on json_schema and notes.



    


    
      
        parse_response(response, opts)

      


        Parse endpoint response.



    


    
      
        retry_prompt(params, resp_params, errors, response, opts)

      


        Updates params with prompt for retrying a request.



    


    
      
        send_request(params, opts)

      


        Make request to API.



    





      


      
        Functions


        


  
    
      
    
    
      find_output(response, opts)



        
          
        

    

  


  

Parse API response in search of plain text output.
Can return:
	{:ok, text_output} on success.
	{:error, :refusal, reason} on refusal.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      initial_prompt(params, opts)



        
          
        

    

  


  

Updates params with prompt based on json_schema and notes.
It uses instructions parameter for system prompt.
Also specifies default gpt-4o-mini model if not provided by a user. 

  



  
    
      
    
    
      parse_response(response, opts)



        
          
        

    

  


  

Parse endpoint response.
Can return:
	{:ok, parsed_json} on success.
	{:error, :refusal, reason} on refusal.
	{:error, :unexpected_response, response} if response is of unexpected shape.


  



  
    
      
    
    
      retry_prompt(params, resp_params, errors, response, opts)



        
          
        

    

  


  

Updates params with prompt for retrying a request.
If the initial request was made with conversation state (enabled by
default), it will drop previous chat messages from the request and specify
previous_response_id instead. If conversation state is disabled, it will
append new messages to the previous input the same way chat completions-based
adapters do.

  



  
    
      
    
    
      send_request(params, opts)



        
          
        

    

  


  

Make request to API.
Options
	:api_key (String.t/0) - Required. API key

	:http_client (atom/0) - Any module that follows Req.post/2 interface The default value is Req.

	:http_options (keyword/0) - Options passed to http_client.post/2 The default value is [receive_timeout: 60000].

	:url (String.t/0) - API endpoint to use for sending requests The default value is "https://api.openai.com/v1/responses".

